Un petit script bien utile

1ere partie
Un lecteur de Mac OS X Hints a créé un petit script bien utile qui permet de sélectionner du texte sur une page web et de le transférer automatiquement dans un fichier texte en y ajoutant la date, l’URL, le titre de la page ainsi que celui de l’article duquel est extrait le texte :
Le script (pour Safari) :
tell application "Safari"
 set selecTxt to (do JavaScript "(getSelection())" in document 1)
 set theurl to (get URL of document 1)
 set pgTitl to (do JavaScript "document.title" in document 1)
end tell
set dat to (current date) as text
set clipFil to (path to desktop folder as text) & "BrowserClips.txt"
try
 close access file clipFil
end try
set filRef to open for access file clipFil with write permission
write (dat & return & (theurl) & return & (pgTitl) & return & "-------------------" & return & selecTxt & return & " " & ¬
 return & return) to filRef starting at eof
close access filRef
tell application "Safari" to activate

Et pour Firefox :
tell application "Firefox"
 activate
 set theurl to « class curl » of window 1
 set pgTitl to « class pTit » of window 1
end tell
tell application "System Events" to keystroke "c" using command down
tell me to activate
set selecTxt to the clipboard as text
tell application "Firefox" to activate
set dat to (current date) as text
set clipFil to (path to desktop folder as text) & "BrowserClips.txt"
try
 close access file clipFil
end try
set filRef to open for access file clipFil with write permission
write (dat & return & (theurl) & return & (pgTitl) & return & "-------------------" & return & selecTxt & return & " " & ¬
 return & return) to filRef starting at eof
close access filRef
Le fichier texte est enregistré automatiquement sur le bureau. Voici le résultat obtenu en sélectionnant un passage de cet article publié dans nos pages :

À noter que le script enregistre toujours ces informations dans le même fichier. Si vous répétez l’opération, les informations s’inscrivent les unes à la suite des autres :

2e partie
Maintenant, si vous n’êtes pas familier avec les rouages d’AppleScript, vous devez sûrement vous demander que faire avec les deux scripts plus haut. Rien de plus simple.
Lancez tout d’abord l’éditeur de scripts qui se trouve dans le dossier AppleScript du dossier Applications afin d’ouvrir la fenêtre d’édition :

Copiez ensuite le script et collez-le dans la fenêtre :

Cliquez sur Enregistrez sous et donnez-lui un nom qui vous permettra de l’identifier facilement. À cette étape, deux choix s’offrent à vous. Vous pouvez enregistrer le script sous le format Script, auquel cas il est recommandé de le ranger dans Utilisateurs/votre nom/Bibliothèque/Scripts afin de l’avoir sous la main dans la barre des menus * :

Vous pouvez également l’enregistrer comme application

3e partie (facultatif)

Voici quelques modifications que vous pouvez apporter au script
Vous noterez en lisant le script, la ligne où est inscrit BrowserClips.txt entre guillemets. Il s’agit du nom du fichier dans lequel le script enregistre les informations extraites des pages web. Vous pouvez le modifier à votre guise en le nommant par exemple Extraits du web.txt.
Vous pouvez également modifier l’endroit où sera rangé le fichier texte. Sur la ligne où est inscrit set clipFil to (path to desktop folder as text) & "BrowserClips.txt", remplacez desktop par un de ces dossiers (merci à Joey sur les forums pour l’info). Par exemple, pour que le fichier soit rangé dans le dossier Documents, substituez tout simplement documents à desktop (set clipFil to (path to documents folder as text).
Si le dossier dans lequel vous souhaitez ranger le fichier texte ne correspond à aucun de ceux mentionnés dans le lien plus haut, remplacez la ligne où est inscrit set clipFil to (path to desktop folder as text) & "BrowserClips.txt" par set clipFil to ((choose folder) as text) & "BrowserClips.txt". Cette nouvelle commande ouvrira une boîte de dialogue durant l’exécution du script et vous permettra de sélectioner le dossier de destination de votre choix (merci à David pour l’info).
Et voilà !
*Pour afficher l’icône d’AppleScritpt dans la barre de menus, il suffit de lancer l’utilitaire AppleScript qui se trouve dans le dossier AppleScript du dossier Applications et cocher la case Afficher le menu des scripts dans la barre de menus.